Cara Membuat Jam Digital Menggunakan Dot Matrix LED

Pendahuluan

Jam digital adalah salah satu proyek elektronika yang paling populer di kalangan penggemar mikrokontroler. Selain fungsional, proyek ini juga memberikan pengalaman praktis dalam mengendalikan tampilan LED, komunikasi dengan modul RTC (Real Time Clock), dan pengolahan waktu secara real-time. Salah satu tampilan yang menarik dan futuristik adalah menggunakan Dot Matrix LED.

Dalam tutorial ini, kita akan membuat jam digital sederhana menggunakan modul Dot Matrix LED MAX7219 yang dapat menampilkan waktu HH:MM secara terus-menerus. Kita akan menggunakan Arduino sebagai otak mikrokontrolernya dan modul RTC DS3231 untuk memastikan waktu tetap akurat bahkan saat mati listrik.

Alat dan Bahan yang Dibutuhkan :

Untuk memulai proyek ini, siapkan komponen berikut:

• 1x Arduino Uno / Nano / ESP8266 / ESP32

• 1x Modul Dot Matrix LED MAX7219 (8X8 4-IN-1 32X8)

• 1x Modul RTC DS3231 (lebih akurat dari DS1307)

• Kabel jumper Male to Female 20 Cm

• Breadboard (opsional)

• Power supply 12V 2A 24W

• Kardur bekas Handphone atau Casing akrilik atau 3D print untuk tampilan lebih rapi

Skema Rangkaian

Hubungkan komponen-komponen berikut:

Koneksi Dot Matrix LED (MAX7219) ke Arduino:

MAX7219 Pin	Arduino Pin
VCC	I OREF
GND	GND
DIN	D11 (MOSI)
CS	D10
CLK	D13

Koneksi DS3231 RTC ke Arduino:

DS3231 Pin	Arduino Pin
GND	GND
VCC	5V
SDA	A4
SCL	A5

Untuk ESP8266/ESP32, sesuaikan pin I2C dan SPI sesuai board yang kamu gunakan.

Persiapan Software

1. Install Arduino IDE

Kamu bisa mengunduhnya dari https://www.arduino.cc/en/software

2. Install Library yang Dibutuhkan

Buka Library Manager dan cari serta install:

• MD_Parola

• MD_MAX72XX

• RTClib (oleh Adafruit)

---

Coding Arduino

Berikut kode dasar jam digital menggunakan MD_Parola dan DS3231:

#include <MD_Parola.h>
#include <MD_MAX72xx.h>
#include <Wire.h>

#define DS3231_I2C_ADDRESS 0x68
#define HARDWARE_TYPE MD_MAX72XX::FC16_HW
#define MAX_DEVICES 4
#define CS_PIN 10

MD_Parola myDisplay = MD_Parola(HARDWARE_TYPE, CS_PIN, MAX_DEVICES);

byte second, minute, hour, dayOfWeek, dayOfMonth, month, year;
int jam, menit;
String waktu = "00:00", waktuNoDot;
unsigned long mulai;
bool kedip = true;

void setDS3231time(byte second, byte minute, byte hour, byte dayOfWeek, byte dayOfMonth, byte month, byte year);

void setup() {
  Serial.begin(9600);
  myDisplay.begin();
  myDisplay.setIntensity(0);    //kecerahan 0-15
  myDisplay.displayClear();
  Wire.begin();
  //Atur Waktu
  setDS3231time(0,5,11,5,18,04,25);// DS3231 seconds, minutes, hours, day, date, month, year
  mulai=millis();
}

void loop() {
  getWaktu();
  if(millis()-mulai > 500){
    kedip=!kedip;
    mulai=millis();
  }
  if(kedip){
    show(waktu);
  }else{
    show(waktuNoDot);
  }
}

void show(String s){
  myDisplay.setTextAlignment(PA_CENTER);  //PA_LEFT, PA_RIGHT 
  myDisplay.print(s);              //myDisplay.setInvert(true);
}

void getWaktu(){
  readDS3231time(&second, &minute, &hour, &dayOfWeek, &dayOfMonth, &month, &year);
  jam     = hour;
  menit   = minute;
  Serial.println(String() + jam + ":" + menit);
  waktu = String() +(jam<10?"0":"")+ jam + ":" +(menit<10?"0":"")+ menit;
  waktuNoDot = String() +(jam<10?"0":"")+ jam + " " +(menit<10?"0":"")+ menit;
}

byte decToBcd(byte val){              // Convert normal decimal numbers to binary coded decimal
  return( (val/10*16) + (val%10) );
}

byte bcdToDec(byte val){              // Convert binary coded decimal to normal decimal numbers
  return( (val/16*10) + (val%16) );
}

void setDS3231time(byte second, byte minute, byte hour, byte dayOfWeek, byte dayOfMonth, byte month, byte year){
  Wire.beginTransmission(DS3231_I2C_ADDRESS);
  Wire.write(0);                      // set next input to start at the seconds register
  Wire.write(decToBcd(second));       // set seconds
  Wire.write(decToBcd(minute));       // set minutes
  Wire.write(decToBcd(hour));         // set hours
  Wire.write(decToBcd(dayOfWeek));    // set day of week (1=Sunday, 7=Saturday)
  Wire.write(decToBcd(dayOfMonth));   // set date (1 to 31)
  Wire.write(decToBcd(month));        // set month
  Wire.write(decToBcd(year));         // set year (0 to 99)
  Wire.endTransmission();
}

void readDS3231time(byte *second,byte *minute,byte *hour,byte *dayOfWeek,byte *dayOfMonth,byte *month,byte *year){
  Wire.beginTransmission(DS3231_I2C_ADDRESS);
  Wire.write(0);                                  // set DS3231 register pointer to 00h
  Wire.endTransmission();
  Wire.requestFrom(DS3231_I2C_ADDRESS, 7);        // request seven bytes of data from DS3231 starting from register 00h
  *second = bcdToDec(Wire.read() & 0x7f);
  *minute = bcdToDec(Wire.read());
  *hour = bcdToDec(Wire.read() & 0x3f);
  *dayOfWeek = bcdToDec(Wire.read());
  *dayOfMonth = bcdToDec(Wire.read());
  *month = bcdToDec(Wire.read());
  *year = bcdToDec(Wire.read());
}

Hasil dan Pengujian

Setelah upload, kamu akan melihat waktu tampil pada modul Dot Matrix LED dengan format HH:MM. Angka akan berganti secara real-time setiap menit. Jika kamu melihat angka acak atau tidak menyala:

• Cek arah koneksi modul MAX7219 (harus dari input ke output)

• Pastikan semua kabel terhubung kuat

• Cek apakah RTC DS3231 terdeteksi (bisa diuji dengan contoh dari RTClib)

---

Penutup

Dengan proyek ini, kamu telah berhasil membuat jam digital dengan tampilan keren menggunakan Dot Matrix LED. Selain menambah estetika ruangan, proyek ini juga memberikan pemahaman praktis soal SPI, I2C, dan manajemen waktu.

Ide Pengembangan:

• Tambahkan animasi transisi waktu (scrolling, efek blink)

• Sinkronisasi waktu via Wi-Fi (ESP8266/ESP32 + NTP)

• Tambah suhu/kelembaban dari sensor DHT11/22

• Gunakan sensor cahaya untuk atur kecerahan otomatis